visualg_algoritmos_aula14+exercícios

Esta é uma pré-visualização de arquivo. Entre para ver o arquivo original

aula14/aula-pratica/p01-TotalPares.alg
algoritmo "TotalPares"
// =============================================================
// Algoritmo para preencher um vetor e mostrar os que sao pares.
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 n: vetor[1..7] de Inteiro
 i, TotPar: Inteiro
inicio
 Para i <- 1 ate 7 faca
 Escreva("Digite o ", i, "o. valor: ")
 Leia(n[i])
 FimPara
 
 LimpaTela
 
 Para i <- 1 ate 7 faca
 Se (n[i] % 2 = 0) entao
 TotPar <- TotPar + 1
 EscrevaL("Valor ", n[i], " na posicao ", i, " e PAR!")
 FimSe
 FimPara
fimalgoritmo
aula14/aula-pratica/p02-ListagemAlunos.alg
algoritmo "ListagemAlunos"
// =============================================================
// Algoritmo para mostrar uma listagem de alunos.
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 nome: vetor[1..5] de Caractere
 nota1: vetor[1..5] de Real
 nota2: vetor[1..5] de Real
 media: vetor[1..5] de Real
 SMed, MTurma: Real
 i: Inteiro
inicio
 Para i <- 1 ate 5 faca
 EscrevaL("--------------------")
 EscrevaL("DADOS DO ALUNO ", i)
 EscrevaL("--------------------")
 Escreva("Nome: ")
 Leia(nome[i])
 Escreva("Nota 1: ")
 Leia(nota1[i])
 Escreva("Nota 2: ")
 Leia(nota2[i])
 Escreva("Media: ")
 media[i] <- (nota1[i] + nota2[i])/2
 EscrevaL(media[i]:4:1)
 SMed <- SMed + media[i]
 FimPara
 // ----- HORA DE CALCULAR A SAIDA -----
 LimpaTela
 MTurma <- Smed / 5
 EscrevaL ("A media da turma e ", MTurma:4:1)
 EscrevaL("-----------------------------------")
 EscrevaL("Alunos que ficaram acima da media")
 EscrevaL("-----------------------------------")
 Para i <- 1 ate 5 faca
 Se (media[i] > MTurma) entao
 EscrevaL(nome[i]:20, media[i]:4:1)
 FimSe
 FimPara
fimalgoritmo
aula14/aula-pratica/p03-SoComC.alg
algoritmo "SoComC"
// =============================================================
// Algoritmo para mostrar uma listagem com nomes que comecem com C
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 nome: Caractere
 soC: vetor[1..10] de Caractere
 c, tot: Inteiro
inicio
 tot <- 0
 Para c <- 1 ate 10 faca
 Escreva("Digite seu nome: ")
 Leia(nome)
 Se (copia(maiusc(nome), 1, 1) = "C") entao
 tot <- tot + 1
 soC[tot] <- nome
 FimSe
 FimPara
 LimpaTela
 EscrevaL("LISTAGEM FINAL")
 Para c <- 1 ate tot faca
 EscrevaL(soC[c])
 FimPara
fimalgoritmo
aula14/aula-pratica/p04-OrdenaVetor.alg
algoritmo "OrdenaVetor"
// =============================================================
// Algoritmo para ordenar um vetor.
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 v: vetor[1..10] de Inteiro
 c: Inteiro
 
Procedimento OrdenaVetor()
var
 i, j, aux: Inteiro
inicio
 Para i <- 1 ate 9 faca
 Para j <- i+1 ate 10 faca
 Se (v[i] > v[j]) entao
 aux <- v[i]
 v[i] <- v[j]
 v[j] <- aux
 FimSe
 FimPara
 FimPara
FimProcedimento
inicio
 Para c <- 1 ate 10 faca
 Escreva("Digite o ", c, "o. valor: ")
 Leia(v[c])
 FimPara
 
 OrdenaVetor()
 
 EscrevaL("-------------------------------")
 EscrevaL("Vetor Ordenado: ")
 EscrevaL("-------------------------------")
 Para c <- 1 ate 10 faca
 Escreva (v[c], " ")
 FimPara
fimalgoritmo
aula14/exercicios-prontos/e01-TorneioFutebol.alg
algoritmo "TorneioFutebol"
// =============================================================
// Algoritmo para verificar o resultado de uma partida de futebol
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 time: vetor[1..3] de Caractere
 l, c: Inteiro
inicio
 EscrevaL("------------------")
 EscrevaL("CAMPEONATO FUTEBOL")
 EscrevaL("------------------")
 Para c <- 1 ate 3 faca
 Escreva ("Nome do ", c, "o. time: ")
 Leia(time[c])
 FimPara
 
 LimpaTela
 EscrevaL("-------------------")
 EscrevaL(" TABELA DE PARTIDAS")
 EscrevaL("-------------------")
 Para l <- 1 ate 3 faca
 Para c <- 1 ate 3 faca
 Se (l <> c) entao
 EscrevaL(time[l]:12, " [ ] x [ ] ", time[c]:12)
 FimSe
 FimPara
 FimPara
fimalgoritmo
aula14/exercicios-prontos/e02-CorrigeProvas.alg
algoritmo "CorrigeProvas"
// =============================================================
// Algoritmo para corrigir uma prova, a partir de um gabarito.
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 gab: vetor[1..5] de Caractere
 prova: vetor[1..5] de Caractere
 nome: vetor[1..3] de Caractere
 nota: vetor[1..3] de Real
 a: Inteiro
 s, m: Real
 
Procedimento CadastroGabarito()
var
 c: Inteiro
inicio
 EscrevaL("PASSO 1 - Cadastro de Gabarito ")
 EscrevaL("-------------------------------")
 Para c <- 1 ate 5 faca
 Escreva("Questao ", c, ": ")
 Leia(gab[c])
 FimPara
FimProcedimento
Funcao CadastraProva(): Real
var
 c: Inteiro
 notaFinal: Real
inicio
 notaFinal <- 0
 EscrevaL("RESPOSTAS DADAS")
 Para c <- 1 ate 5 faca
 Escreva("Questao ", c, ": ")
 Leia(prova[c])
 Se (Maiusc(prova[c]) = Maiusc(gab[c])) entao
 notaFinal <- notaFinal + 2
 FimSe
 FimPara
 Retorne notaFinal
FimFuncao
inicio
 CadastroGabarito()
 
 Para a <- 1 ate 3 faca
 LimpaTela
 EscrevaL("------------------------")
 EscrevaL("ALUNO ", a)
 EscrevaL("------------------------")
 Escreva("Nome: ")
 Leia(nome[a])
 nota[a] <- CadastraProva()
 s <- s + nota[a]
 FimPara
 LimpaTela
 EscrevaL("NOTAS FINAIS ")
 EscrevaL("-----------------------------")
 Para a <- 1 ate 3 faca
 EscrevaL(nome[a]:10, nota[a]:4:1)
 FimPara
 m <- s / 3
 EscrevaL("-----------------------------")
 EscrevaL("Media da Turma: ", M:4:1)
fimalgoritmo
aula14/exercicios-prontos/e03-LugaresCinema.alg
algoritmo "LugaresCinema"
// =============================================================
// Algoritmo para reservar lugares em uma sala de cinema.
//
// AUTOR: Gustavo Guanabara
// Curso COMPLETO disponivel GRATIS no site www.cursoemvideo.com
// =============================================================
var
 B: vetor[1..19] de Caractere
 l, cad: Inteiro
 r: Caractere
 
Procedimento MostraFileira()
var i: Inteiro
inicio
 Para i <- 1 ate 10 faca
 Se (B[i] = "") entao
 Escreva ("[ B", i:2, " ]")
 senao
 Escreva ("[ --- ]")
 FimSe
 FimPara
 EscrevaL()
 EscrevaL("------------------------------------------------------------------------")
FimProcedimento
inicio
 Repita
 LimpaTela
 MostraFileira()
 Escreva("Reservar a cadeira: B")
 Leia(cad)
 Se (B[cad]="") entao
 B[cad] <- "X"
 EscrevaL("Cadeira B", cad, " RESERVADA!")
 Senao
 EscrevaL("ERRO: Lugar Ocupado!")
 FimSe
 Escreva("Quer reservar outro? [S/N] ")
 Leia(r)
 Ate (r = "N")
fimalgoritmo