Apostila de Algoritmos (Visualg)

Prévia do material em texto

Lógica de Programação 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
TÉCNICO EM MANUTENÇÃO E SUPORTE EM INFORMÁTICA 
MÓDULO I 
 
 
 
 
CAMPUS 
BIRIGUI 
 
 
 2 
Introdução a Lógica de Programação 
 
A lógica trata da correção do pensamento, isto é, ela nos ensina a usar corretamente o raciocínio. 
Pensar com lógica significa ordenar o pensamento. 
Para resolver um determinado problema é necessário raciocinar de forma lógica ordenando o 
pensamento com o objetivo de atingir a solução pretendida. 
A lógica está presente no nosso cotidiano, nas nossas ações, quando falamos, ou escrevemos, pois 
quando queremos falar, escrever ou agir corretamente precisamos ordenar nosso pensamento. 
Algoritmo pode ser definido como uma seqüência lógica, e sem ambigüidade de passos que levam a 
solução de um dado problema. É uma seqüência de passos que visam atingir um objetivo bem definido. 
O algoritmo está presente em todas as ações do nosso dia-a-dia como se fosse um plano para 
resolução de problemas. 
Os algoritmos são comuns em nosso cotidiano, como por exemplo, uma receita de bolo. Nela está 
descrita uma série de ingredientes necessários, uma seqüência de passos a serem cumpridos para atingir o 
objetivo que é ter um bolo pronto. Ou então um mapa para chegar até a Faculdade que descreve o caminho a 
ser percorrido através de uma seqüência de passos. 
Podemos descrever atividades do cotidiano como, por exemplo, trocar uma lâmpada queimada. Apesar 
de aparentemente óbvio demais, muitas vezes fazemos esse tipo de atividade sem percebermos determinados 
detalhes. De maneira simples podemos descrever: 
 
 pegue uma escada; 
 posicione-a embaixo da lâmpada queimada; 
 pegue uma lâmpada nova; 
 suba na escada; 
 retire a lâmpada velha; 
 coloque a lâmpada nova 
 desça e guarde a escada. 
 
A seqüência descrita supõe que a lâmpada nova não esteja queimada e que se tenha apenas uma 
lâmpada para ser trocada. 
Se tivermos uma outra situação: várias lâmpadas que precisam ser testadas e trocadas ou não, 
conforme sua condição, a seqüência de passos para a solução do problema será outra. 
Para resolvermos um problema através da construção de um algoritmo podemos especificar um 
método que traduza uma seqüência lógica de passos: 
 
 Ler atentamente o enunciado - para resolver um problema é necessária sua compreensão; 
 Retirar do enunciado a relação das entradas de dados - através do enunciado podemos descobrir quais 
são as informações que devem ser fornecidas, a partir das quais desenvolveremos as ações; 
 Retirar do enunciado a relação das saídas de dados - através do enunciado podemos descobrir quais são 
os dados que devem ser emitidos para compor o resultado final, objetivo do algoritmo; 
 Determinar as ações que levarão a atingir o resultado desejado - nesta etapa precisamos determinar qual 
seqüência de ações é capaz de transformar um conjunto definido de dados nas informações de resultado; 
 Construir o algoritmo - descrever os passos para resolver o problema; 
 Executar o algoritmo - implica em executar todas as ações descritas seguindo o fluxo de execução 
estabelecido, verificando se os resultados obtidos correspondem ao esperado. Desta forma torna-se 
possível detectar algum possível erro no desenvolvimento do algoritmo. Essa atividade é conhecida como 
“TESTE DE MESA”. 
 
TODO O CONTEÚDO DESTE MATERIAL FOI RETIRADO DO SITE ABAIXO. 
Nesta disciplina usaremos o software VisuAlg para o desenvolvimento dos algoritmos. O link para baixar o 
programa Visualg é o seguinte: 
http://www.apoioinformatica.inf.br/ 
A linguagem do VisuAlg permite apenas um comando por linha: desse modo, não há necessidade de tokens 
separadores de estruturas, como o ponto e vírgula em Pascal. Também não existe o conceito de blocos de 
 3 
comandos (que correspondem ao begin e end do Pascal e ao { e } do C), nem comandos de desvio 
incondicional como o goto. Na versão atual do VisuAlg, com exceção das rotinas de entrada e saída, não há 
nenhum subprograma embutido, tal como Inc(), Sqr(), Ord(), Chr(), Pos(), Copy() ou outro. 
Importante: para facilitar a digitação e evitar confusões, todas as palavras-chave do VisuAlg foram 
implementadas sem acentos, cedilha, etc. Portanto, o tipo de dados lógico é definido como logico, o 
comando se..então..senão é definido como se..entao..senao, e assim por diante. O VisuAlg também não 
distingue maiúsculas e minúsculas no reconhecimento de palavras-chave e nomes de variáveis. 
Formato Básico do Algoritmo e Inclusão de Comentários 
O formato básico do nosso algoritmo é o seguinte: 
algoritmo "semnome" 
// Função : 
// Autor : 
// Data : 
// Seção de Declarações 
inicio 
// Seção de Comandos 
fimalgoritmo 
A primeira linha é composta pela palavra-chave algoritmo seguida do seu nome delimitado por aspas 
duplas. Este nome será usado como título nas janelas de leitura de dados (nas futuras versões do VisuAlg, 
talvez utilizemos este dado de outras formas). A seção que se segue é a de declaração de variáveis, que 
termina com a linha que contém a palavra-chave inicio. Deste ponto em diante está a seção de comandos, 
que continua até a linha em que se encontre a palavra-chave fimalgoritmo. Esta última linha marca o final 
do pseudocódigo: todo texto existente a partir dela é ignorado pelo interpretador. 
O VisuAlg permite a inclusão de comentários: qualquer texto precedido de "//" é ignorado, até se atingir o final 
da sua linha. Por este motivo, os comentários não se estendem por mais de uma linha: quando se deseja 
escrever comentários mais longos, que ocupem várias linhas, cada uma delas deverá começar por "//". 
Tipos de Dados 
O VisuAlg prevê quatro tipos de dados: inteiro, real, cadeia de caracteres e lógico (ou booleano). As 
palavras-chave que os definem são as seguintes (observe que elas não têm acentuação): 
 inteiro: define variáveis numéricas do tipo inteiro, ou seja, sem casas decimais. 
 real: define variáveis numéricas do tipo real, ou seja, com casas decimais. 
 caractere: define variáveis do tipo string, ou seja, cadeia de caracteres. 
 logico: define variáveis do tipo booleano, ou seja, com valor VERDADEIRO ou FALSO. 
 
Nomes de Variáveis e sua Declaração 
Os nomes das variáveis devem começar por uma letra ou por um underline ( _ ) e depois conter letras, 
números ou underline, até um limite de 30 caracteres. Não pode haver duas variáveis com o mesmo nome. 
A seção de declaração de variáveis começa com a palavra-chave var, e continua com as seguintes sintaxes: 
<lista-de-variáveis> : <tipo-de-dado> 
 
Na <lista-de-variáveis>, os nomes das variáveis estão separados por vírgulas. 
 4 
Exemplos: 
var 
 a: inteiro 
 Valor1, Valor2: real 
 nome_do_aluno: caractere 
 sinalizador: logico 
Note que não há a necessidade de ponto e vírgula após cada declaração: basta pular linha. 
Exercícios 
 
1) Quais as variáveis não válidas? Explique o motivo. 
 
abc  
ah-  
function  
sal_liquido  
sala215  
nomedaempresa  
3formas  
ano base  
_a123  
 
2) Supondo que as variáveis nome, prof, id e salario sejam utilizados para armazenar nome, código de 
profissão (no. inteiro), idade e salário de uma pessoa, escrever o conjunto de declarações necessário para criar 
estas variáveis e associar às mesmas nos respectivos tipos pré-definidos. 
 
3) Agora, escreva a declaração var, escolhendo os nomes para as variáveis usadas com as seguintes 
finalidades: 
CEP, matrícula da faculdade, número de dependentes, altura, situação funcional (aposentado/ normal/ 
licenciado), nível superior (sim ou não) 
 
Constantes e Comando de Atribuição 
O VisuAlg tem três tipos de constantes: 
 Numéricos:são valores numéricos escritos na forma usual das linguagens de programação. Podem ser 
inteiros ou reais. Neste último caso, o separador de decimais é o ponto e não a vírgula, independente 
da configuração regional do computador onde o VisuAlg está sendo executado. O VisuAlg também não 
suporta separadores de milhares. 
 Caracteres: qualquer cadeia de caracteres delimitada por aspas duplas ("). 
 Lógicos: admite os valores VERDADEIRO ou FALSO. 
A atribuição de valores a variáveis é feita com o operador <-. Do seu lado esquerdo fica a variável à qual está 
sendo atribuído o valor, e à sua direita pode-se colocar qualquer expressão (constantes, variáveis, expressões 
numéricas), desde que seu resultado tenha tipo igual ao da variável. 
Alguns exemplos de atribuições, usando as variáveis declaradas acima: 
a <- 3 
Valor1 <- 1.5 
Valor2 <- Valor1 + a 
nome_do_aluno <- "José da Silva" 
sinalizador <- FALSO 
 5 
A Linguagem de Programação do VisuAlg 
 
Operadores Aritméticos 
+,- 
Operadores unários, isto é, são aplicados a um único operando. São os operadores aritméticos de 
maior precedência. Exemplos: -3, +x. Enquanto o operador unário - inverte o sinal do seu 
operando, o operador + não altera o valor em nada o seu valor. 
\ Operador de divisão inteira. Por exemplo, 5 \ 2 = 2. Tem a mesma precedência do operador de 
divisão tradicional. 
+,-
,*,/ 
Operadores aritméticos tradicionais de adição, subtração, multiplicação e divisão. Por convenção, * e 
/ têm precedência sobre + e -. Para modificar a ordem de avaliação das operações, é necessário 
usar parênteses como em qualquer expressão aritmética. 
MOD ou 
% 
Operador de módulo (isto é, resto da divisão inteira). Por exemplo, 8 MOD 3 = 2. Tem a mesma 
precedência do operador de divisão tradicional. 
^ Operador de potenciação. Por exemplo, 5 ^ 2 = 25. Tem a maior precedência entre os operadores 
aritméticos binários (aqueles que têm dois operandos). 
Operadores de Caracteres 
+ 
Operador de concatenação de strings (isto é, cadeias de caracteres), quando usado com dois valores 
(variáveis ou constantes) do tipo "caractere". Por exemplo: "Rio " + " de Janeiro" = "Rio 
de Janeiro". 
Operadores Relacionais 
=, <, 
>, <=, 
>=, 
<> 
Respectivamente: igual, menor que, maior que, menor ou igual a, maior ou igual a, diferente de. São 
utilizados em expressões lógicas para se testar a relação entre dois valores do mesmo tipo. 
Exemplos: 3 = 3 ( 3 é igual a 3?) resulta em VERDADEIRO ; "A" > "B" ("A" está depois de "B" na 
ordem alfabética?) resulta em FALSO. 
Importante: No VisuAlg, as comparações entre strings não diferenciam as letras maiúsculas das minúsculas. 
Assim, "ABC" é igual a "abc". Valores lógicos obedecem à seguinte ordem: FALSO < VERDADEIRO. 
Operadores Lógicos 
nao 
Operador unário de negação. nao VERDADEIRO = FALSO, e nao FALSO = VERDADEIRO. Tem a 
maior precedência entre os operadores lógicos. Equivale ao NOT do Pascal. 
ou 
Operador que resulta VERDADEIRO quando um dos seus operandos lógicos for verdadeiro. Equivale 
ao OR do Pascal. 
e 
Operador que resulta VERDADEIRO somente se seus dois operandos lógicos forem verdadeiros. 
Equivale ao AND do Pascal. 
 
X Y X e Y X ou Y 
VERDADEIRO VERDADEIRO 
FALSO VERDADEIRO 
VERDADEIRO FALSO 
FALSO FALSO 
 
 
 6 
Exercícios 
 
1) Considere as variáveis A, B, C, D e E com os respectivos valores 127, 10, 5, falso e verdadeiro. Qual é o 
valor produzido por cada uma das sentenças abaixo? 
a) não D 
b) D e E 
c) (A>=B) ou (B<C) 
d) não (A< B) 
e) (D e E) ou (A=B) 
f) (D ou E) e (A< B) 
 
2) Se A e B são variáveis inteiras e X é variável real, sendo A = 10, B = 3 e X = 2.5, os resultados fornecidos 
pelas seguintes expressões são: 
 
a) A \ B d) X \ 2 
b) A mod B e) X % 2 
c) A / B 
 
3) Com as declarações: 
 
 var 
 x, y, z: inteiro 
 nome, cor: caracter 
 inicio 
 x <-1 
 y <- 2 
 cor <- “azul” 
 nome <- “Paulo” 
 z <- 5 
 fimalgoritmo 
 
 Dê o resultado para as seguintes expressões: 
a) x * x + y > z 
b) cor = “azul” 
c) nome <> “Jose” 
d) x <= z 
 
4) Dado o seguinte algoritmo: 
 
algoritmo “facil” 
var 
 Ok, teste, p, q, r, s : logico 
 a, b: inteiro 
inicio 
 Ok <- verdadeiro 
 a <- 0 
 b <- 2 
 teste <- falso 
 p <- Ok 
 q <- a = 0 
 r <- teste 
 s <- b <> 1 
fimalgoritmo 
 
Qual o valor lógico das conjunções? 
a) p E s 
b) p E r 
c) p OU s 
d) p OU r 
e) q E s 
 7 
f) q E r 
g) q OU s 
h) q OU r 
 
5) Faça um algoritmo chamado tentativa e declare nele 5 variáveis, sendo que 2 deles armazenarão números 
inteiros; 1 conterá número real; 1 armazenará valor lógico e o outro um caracter. 
 
6) Escreva um algoritmo que declare 3 variáveis inteiras e atribua os valores 1, 2 e 3 a elas; 3 variáveis 
caracteres e atribua a elas as letras a, b e c ; 1 variável real com o valor 5.68. 
 
7) Declare 3 variáveis e atribua a eles o seu nome, a sua idade e o seu sexo ( “M” ou “F”). 
 
Comandos de Saída de Dados 
escreva (<lista-de-expressões>) 
Escreve no dispositivo de saída padrão (isto é, na área à direita da metade inferior da tela do VisuAlg) o 
conteúdo de cada uma das expressões que compõem <lista-de-expressões>. As expressões dentro 
desta lista devem estar separadas por vírgulas; depois de serem avaliadas, seus resultados são impressos na 
ordem indicada. É equivalente ao comando write do Pascal. 
De modo semelhante a Pascal, é possível especificar o número de espaços no qual se deseja escrever um 
determinado valor. Por exemplo, o comando escreva(x:5) escreve o valor da variável x em 5 espaços, 
alinhado-o à direita. Para variáveis reais, pode-se também especificar o número de casas fracionárias que 
serão exibidas. Por exemplo, considerando y como uma variável real, o comando escreva(y:6:2)escreve 
seu valor em 6 espaços colocando 2 casas decimais. 
escreval (<lista-de-expressões>). 
Idem ao anterior, com a única diferença que pula uma linha em seguida. É equivalente ao writeln do Pascal. 
Exemplos: 
algoritmo "exemplo" 
var x: real 
 y: inteiro 
 a: caractere 
 m: logico 
inicio 
 x <- 2.5 
 y <- 6 
 a <- "teste" 
 m <- VERDADEIRO 
 escreval ("x", x:4:1, y+3:4) // Escreve: x 2.5 9 
 escreval (a, "ok") // Escreve: testeok (e depois pula linha) 
 escreval (a, " ok") // Escreve: teste ok (e depois pula linha) 
 escreval (a + " ok") // Escreve: teste ok (e depois pula inha) 
 escreva (m) // Escreve: VERDADEIRO 
fimalgoritmo 
Note que o VisuAlg separa expressões do tipo numérico e lógico com um espaço à esquerda, mas não as 
expressões do tipo caractere, para que assim possa haver a concatenação. Quando se deseja separar 
expressões do tipo caractere, é necessário acrescentar espaços nos locais adequados. 
 
 8 
Comando de Entrada de Dados 
leia (<lista-de-variáveis>) 
Recebe valores digitados pelos usuário, atribuindo-os às variáveis cujos nomes estão em <lista-de-
variáveis> (é respeitada a ordem especificada nesta lista). É análogo ao comando read do Pascal. 
Veja no exemplo abaixo o resultado: 
algoritmo "exemplo 1" 
var x: inteiro; 
inicio 
 leia (x) 
 escreva (x) 
fimalgoritmo 
Exercícios 
 
1) Faça um algoritmo para que dado 2 números inteiros quaisquer, imprimi-los na tela. 
 
2) Ler dois valores inteiros e efetuar as operações de adição, subtração, multiplicação e divisão de A por B, 
apresentando no final os quatro resultados obtidos. 
 
3) Faça um algoritmo para que dado 4 notas quaisquer, calcule a média aritmética dessas notas. 
 
4) Calcular 20% de um valor qualquerdigitado pelo usuário 
 
5) Faça um algoritmo que receba o ano de nascimento de uma pessoa e o ano atual, calcule e mostre: 
 a idade dessa pessoa; 
 quantos anos essa pessoa terá em 2020. 
 
6) Faça um algoritmo que receba três notas e seus respectivos pesos, calcule e mostre a média ponderada 
dessas notas. 
media <- (nota1  peso1 + nota2  peso2 + nota3  peso3) / (peso1 + peso2 + peso3) 
 
7) Construir um algoritmo que efetue o cálculo do salário líquido de um professor. Para fazer este programa 
você deverá possuir alguns dados, tais como: valor da hora aula, número de aulas dadas no mês e percentual 
de desconto do INSS. Em primeiro lugar, deve-se estabelecer qual será o seu salário bruto para efetuar o 
desconto e ter o valor do salário líquido. 
 
8) Ler dois valores para as variáveis A e B, efetuar a troca dos valores de forma que a variável A passe a 
possuir o valor da variável B e que B passe a possuir o valor da variável A apresentar os valores trocados. 
 
9) Efetuar o cálculo da quantidade de litros de combustível gastos em uma viagem, utilizando-se um automóvel 
que faz 12 km por litro. Para obter o cálculo, o usuário deverá fornecer o tempo gasto na viagem e a velocidade 
média durante a mesma. Desta forma, será possível obter a distância percorrida com a fórmula DISTÂNCIA = 
TEMPO x VELOCIDADE. Tendo o valor da distância, basta calcular a quantidade de litros de combustível 
utilizada na viagem com a fórmula: LITROS USADOS =DISTÂNCIA / 12. Imprimir o resultado final. 
 
10) Uma firma contrata um encanador a R$ 50,00 por dia. Crie um algoritmo que solicite o número de dias 
trabalhados pelo encanador e imprima a quantia líquida que deverá ser paga, sabendo-se que são 
descontados 8% para imposto de renda. 
 
 
 
 9 
Comando de Desvio Condicional 
se <expressão-lógica> entao 
 <seqüência-de-comandos> 
fimse 
Ao encontrar este comando, o VisuAlg analisa a <expressão-lógica>. Se o seu resultado for VERDADEIRO, 
todos os comandos da <seqüência-de-comandos> (entre esta linha e a linha com fimse) são executados. 
Se o resultado for FALSO, estes comandos são desprezados e a execução do algoritmo continua a partir da 
primeira linha depois do fimse. 
se <expressão-lógica> entao 
 <seqüência-de-comandos-1> 
senao 
 <seqüência-de-comandos-2> 
fimse 
Nesta outra forma do comando, se o resultado da avaliação de <expressão-lógica> for VERDADEIRO, 
todos os comandos da <seqüência-de-comandos-1> (entre esta linha e a linha com senao) são 
executados, e a execução continua depois a partir da primeira linha depois do fimse. Se o resultado for 
FALSO, estes comandos são desprezados e o algoritmo continua a ser executado a partir da primeira linha 
depois do senao, executando todos os comandos da <seqüência-de-comandos-2> (até a linha com 
fimse). 
Estes comandos equivalem ao if...then e if...then...else do Pascal. Note que não há necessidade de 
delimitadores de bloco (como begin e end), pois as seqüências de comandos já estão delimitadas pelas 
palavras-chave senao e fimse. O VisuAlg permite o aninhamento desses comandos de desvio condicional. 
Exercícios 
 
1 – Faça um algoritmo para que dado 2 números quaisquer, verificar se são iguais. Caso sejam iguais, imprima 
a mensagem “Os números são iguais”; caso sejam diferentes, imprima a mensagem “Os números são 
diferentes”. 
 
2 - Leia 2 números via teclado. Calcule a sua soma e o seu produto. Se a soma for maior que produto imprima 
a soma, caso contrário imprima o produto. 
 
3 -Elabore um algoritmo que leia o nome da pessoa e a sua idade. Utilizando a tabela abaixo verifique em qual 
item se enquadra a idade do usuário e emita a mensagem: 
 Fulano está com X anos. 
 Pela Tabela é considerado um jovem. 
 
Idades Tipo 
0 – 2 Bebê 
3 – 11 Criança 
12 – 25 Jovem 
26 – 59 Adulto 
acima de 59 Idoso 
 
 
4 – Faça um algoritmo para verificar se um número qualquer é par ou ímpar. Se for par, imprimir “O número é 
par” , caso contrário imprimir “O número é impar”. * 
 
5 - Faça um algoritmo que leia 3 números inteiros e imprima-os em ordem crescente. 
 
6 - Sabendo que em uma loja de brinquedos é dado um desconto dependendo do total de compras, faça um 
programa para a loja em que entrando com o valor total das compras dê o valor final a ser pago pelo cliente 
acrescido com o desconto seguindo a tabela abaixo: 
 10 
 
Compras Descontos 
abaixo $20 - 
$20 - $50 10% 
$50 - $100 20% 
$100 - $300 30% 
acima de $300 50% 
 
valor desconto = (Total de compras X desconto) / 100. 
 
7 - Efetue o cálculo do salário de um funcionário. Considere que o funcionário deverá receber um reajuste de 
15% caso seu salário seja menor que 500, se o salário for maior ou igual a 500 mas menor ou igual a 1000, 
seu reajuste será de 10%, caso seja ainda maior que 1000, o reajuste deverá ser de 5%. Deverá ser mostrado 
o valor do novo salário. 
 
8 - Faça um algoritmo que solicite na tela o nome de uma pessoa, seu endereço, idade, sexo e estado civil. Se 
a pessoa for do sexo masculino (M) e a pessoa for maior de 18 anos então peça também o número do 
certificado de reservista. Se a pessoa for maior de 18 anos cadastre também o número do título de eleitor. 
Imprima todas as informações no final. 
 
9 - Faça um algoritmo que leia 4 notas de alunos, calcule a média e imprima na tela uma mensagem que o 
aluno foi aprovado se a média do aluno foi >= 7. Se a média foi <7 pedir a nota do exame final, calcular a nova 
média que se>= 5 informar então que o aluno foi aprovado por exame final, caso a média seja <5 informe que o 
aluno foi reprovado. 
 
10 - Faça um algoritmo que receba dois números e ofereça um menu de opções de qual operação fazer com 
estes números (soma, subtração, multiplicação e divisão). Escolhida a opção, o programa apresenta o 
resultado da operação escolhida. 
 
11 – Faça um algoritmo que receba a altura e o peso de uma pessoa. De acordo com a tabela a seguir 
verifique e mostre qual a classificação dessa pessoa. 
Altura Peso 
Até 60 Entre 60 e 90 (inclusive) Acima de 90 
Menores que 1.20 A D G 
De 1.20 a 1.70 B E H 
Maiores que 1.70 C F I 
 
Comando de Seleção Múltipla 
O VisuAlg implementa (com certas variações) o comando case do Pascal. A sintaxe é a seguinte: 
escolha <expressão-de-seleção> 
 caso <exp11>, <exp12>, ..., <exp1n> 
 <seqüência-de-comandos-1> 
 caso <exp21>, <exp22>, ..., <exp2n> 
 <seqüência-de-comandos-2> 
 ... 
 outrocaso 
 <seqüência-de-comandos-extra> 
fimescolha 
Veja o exemplo a seguir, que ilustra bem o que faz este comando: 
 11 
algoritmo "Times" 
var time: caractere 
inicio 
 escreva ("Entre com o nome de um time de futebol: ") 
 leia (time) 
 escolha time 
 caso "Flamengo", "Fluminense", "Vasco", "Botafogo" 
 escreval ("É um time carioca.") 
 caso "São Paulo", "Palmeiras", "Santos", "Corínthians" 
 escreval ("É um time paulista.") 
 outrocaso 
 escreval ("É de outro estado.") 
fimescolha 
fimalgoritmo 
Exercícios 
 
1) Faça um algoritmo que receba dois números e ofereça um menu de opções de qual operação fazer com 
estes números (soma, subtração, multiplicação e divisão). Escolhida a opção, o programa apresenta o 
resultado da operação escolhida. 
 
2) Faça um programa que receba a altura e o sexo de uma pessoa e que calcule e mostre o peso ideal, 
utilizando as seguintes fórmulas: 
 para homens: (72.7  h) – 58; 
 para mulheres: (62.1  h) – 44.7 
 
3) Em uma Agência de Turismo existem alguns pacotes de viagens que estão em promoção tanto p/ as 
viagens do Brasil como p/ o Exterior. 
 
Cidades 
Brasileiras 
Preço por 
Pessoa 
 Cidades Estrangeiras Preço por Pessoa 
Rio de Janeiro 700 Nova York 2200 
Salvador900 França 3550 
Porto Alegre 880 Cancun 3900 
 Madri 4000 
 
Monte um algoritmo onde o usuário seleciona se ele deseja uma viagem p/ o exterior ou aqui no Brasil. 
Dependo da escolha seu programa deverá mostrar as cidades correspondentes p/ ele selecionar a cidade. Seu 
programa deverá no final mostrar quanto ficará o valor da viagem, depende da quantidade de pessoas que for 
para a viagem. 
 
Comandos de Repetição 
O VisuAlg implementa as três estruturas de repetição usuais nas linguagens de programação: o laço contado 
para...ate...faca (similar ao for...to...do do Pascal), e os laços condicionados enquanto...faca 
(similar ao while...do) e repita...ate (similar ao repeat...until). A sintaxe destes comandos é explicada a 
seguir. 
Para ... faça 
Esta estrutura repete uma seqüência de comandos um determinado número de vezes. 
para <variável> de <valor-inicial> ate <valor-limite> [passo <incremento>] faca 
 <seqüência-de-comandos> 
fimpara 
 12 
<variável > 
É a variável contadora que controla o número de repetições do laço. Na versão atual, 
deve ser necessariamente uma variável do tipo inteiro, como todas as expressões 
deste comando. 
<valor-inicial> É uma expressão que especifica o valor de inicialização da variável contadora antes 
da primeira repetição do laço. 
<valor-limite > É uma expressão que especifica o valor máximo que a variável contadora pode 
alcançar. 
<incremento > 
É opcional. Quando presente, precedida pela palavra passo, é uma expressão que 
especifica o incremento que será acrescentado à variável contadora em cada 
repetição do laço. Quando esta opção não é utilizada, o valor padrão de 
<incremento> é 1. Vale a pena ter em conta que também é possível especificar 
valores negativos para <incremento>. Por outro lado, se a avaliação da expressão 
<incremento > resultar em valor nulo, a execução do algoritmo será interrompida, 
com a impressão de uma mensagem de erro. 
fimpara 
Indica o fim da seqüência de comandos a serem repetidos. Cada vez que o 
programa chega neste ponto, é acrescentado à variável contadora o valor de 
<incremento >, e comparado a <valor-limite >. Se for menor ou igual (ou 
maior ou igual, quando <incremento > for negativo), a seqüência de comandos 
será executada mais uma vez; caso contrário, a execução prosseguirá a partir do 
primeiro comando que esteja após o fimpara. 
<valor-inicial >, <valor-limite > e <incremento > são avaliados uma única vez antes da 
execução da primeira repetição, e não se alteram durante a execução do laço, mesmo que variáveis 
eventualmente presentes nessas expressões tenham seus valores alterados. 
No exemplo a seguir, os números de 1 a 10 são exibidos em ordem crescente. 
algoritmo "Números de 1 a 10" 
var j: inteiro 
inicio 
 para j de 1 ate 10 faca 
 escreva (j:3) 
 fimpara 
fimalgoritmo 
Importante: Se, logo no início da primeira repetição, <valor-inicial > for maior que <valor-limite > 
(ou menor, quando <incremento> for negativo), o laço não será executado nenhuma vez. O exemplo a seguir 
não imprime nada. 
algoritmo "Numeros de 10 a 1 (não funciona)" 
var j: inteiro 
inicio 
 para j de 10 ate 1 faca 
 escreva (j:3) 
 fimpara 
fimalgoritmo 
Este outro exemplo, no entanto, funcionará por causa do passo -1: 
algoritmo "Numeros de 10 a 1 (este funciona)" 
var j: inteiro 
inicio 
 para j de 10 ate 1 passo -1 faca 
 escreva (j:3) 
 fimpara 
fimalgoritmo 
 13 
Exercícios 
 
1 – Faça um algoritmo para imprimir os números de 1 a 500 na tela. 
 
2 - Utilizando o comando para faça um algoritmo que leia 5 números reais, calcule e imprima a sua somatória e 
a sua média. 
 
3 - Faça um algoritmo que imprima a tabuada de qualquer número lido pelo teclado. 
Exemplo: 
 
Qual o número? 2 
2  1 = 2 
2  2 = 4 
2  3 = 6 
2  4 = 8 
2  5 = 10 
2  6 = 12 
2  7 = 14 
2  8 = 16 
2  9 = 18 
2  10 = 20 
 
4 – Escreva um algoritmo que receba a idade de 10 pessoas, calcule e imprima a quantidade de pessoas 
maiores de 18 anos. 
 
5 – Faça um algoritmo para ler 50 fichas de inscrições, contendo cada uma delas a altura, sexo e idade. 
 Deverá ser impressa a maior e a menor altura; 
 A média de altura das mulheres; 
 Quantos são os homens e quantas são as mulheres 
 
6 – Uma empresa contratou 7 funcionários temporários. De acordo com o valor das vendas mensais, os 
funcionários adquirem pontos que determinarão seus salários ao final de cada mês. Sabe-se que esses 
funcionários trabalharão nos meses de Novembro e Janeiro do ano subseqüente. Faça um algoritmo que: 
 leia as pontuações nos três meses de cada funcionário; 
 calcule e mostre a pontuação geral de cada funcionário nos três meses; 
 calcule e mostre a média das pontuações de cada funcionário nos três meses; 
 determine e mostre a maior pontuação atingida entre todos os funcionários nos três meses. 
 
7 – Faça um algoritmo que receba dois números. Calcule e mostre: 
 a soma dos números pares desse intervalo de números, incluindo os números digitados; 
 a multiplicação dos números ímpares desse intervalo de números, incluindo os números digitados. 
 
Enquanto ... faça 
Esta estrutura repete uma seqüência de comandos enquanto uma determinada condição (especificada através 
de uma expressão lógica) for satisfeita. 
enquanto <expressão-lógica> faca 
 <seqüência-de-comandos> 
fimenquanto 
<expressão-lógica> 
Esta expressão que é avaliada antes de cada repetição do laço. Quando seu 
resultado for VERDADEIRO, <seqüência-de-comandos> é executada. 
fimenquanto Indica o fim da <seqüência-de-comandos> que será repetida. Cada vez 
 14 
que a execução atinge este ponto, volta-se ao início do laço para que 
<expressão-lógica> seja avaliada novamente. Se o resultado desta 
avaliação for VERDADEIRO, a <seqüência-de-comandos> será executada 
mais uma vez; caso contrário, a execução prosseguirá a partir do primeiro 
comando após fimenquanto. 
 O mesmo exemplo anterior pode ser resolvido com esta estrutura de repetição: 
algoritmo "Números de 1 a 10 (com enquanto...faca)" 
var j: inteiro 
inicio 
j <- 1 
enquanto j <= 10 faca 
 escreva (j:3) 
 j <- j + 1 
fimenquanto 
fimalgoritmo 
Importante: Como o laço enquanto...faca testa sua condição de parada antes de executar sua seqüência 
de comandos, esta seqüência poderá ser executada zero ou mais vezes. 
Exercícios 
 
1 - Calcular a soma dos números de 1 a 10. 
 
2 - Faça um algoritmo que receba as 4 notas de alunos e informe sua média até que o nome informado seja 
"FIM". 
 
3 - Faça um algoritmo que receba nome e ano de nascimento. No final diga o nome da pessoa mais velha e da 
mais nova. O programa deve pedir nome de pessoas até que o usuário diga que não tem mais nomes a 
informar, e, então, verificar a mais velha e a mais nova. 
 
4 - Ler nomes do teclado e contar quantos nomes foram lidos para apresentar na tela no final nas seguintes 
situações. O programa receberá nomes até que o nome informado seja "FIM". O programa receberá nomes 
enquanto a pergunta "Há mais nomes a serem informados?" for respondida com "sim". 
 
5 - Dado um conjunto de valores inteiros e positivos, determine qual o menor valor do conjunto. Com o valor -1 
(flag) indique o final dos dados e não deve ser considerado. 
 
6 - Uma empresa decidiu fazer um levantamento em relação aos candidatos que se apresentarem para 
preenchimento de vagas no seu quadro de funcionários, utilizando processamento eletrônico. Supondo que 
você seja o programador encarregado desse levantamento, fazer um programa que: 
 Leia um conjunto de dados para cada candidato contendo: 
a. Número de inscrição do candidato; 
b. Idade; 
c. Sexo (masculino,feminino); 
d. Experiência no serviço (sim ou não). 
O último conjunto contém o número de inscrição do candidato igual a zero. 
 Calcule: 
a. O número de candidatos do sexo feminino; 
b. O número de candidatos do sexo masculino; 
c. Idade média dos homens que já tem experiência no serviço; 
d. Porcentagem dos homens com mais de 45 anos entre o total de homens; 
e. Número de mulheres que tem idade inferior a 35 anos e com experiência no serviço; 
f. A menor idade entre mulheres que já tem experiência no serviço; 
 Escreva: 
a. O que foi calculado em cada item acima especificado. 
 
 15 
7- Faça um algoritmo que receba vários números, calcule e mostre: 
 a soma dos números digitados; 
 a quantidade de números digitados; 
 a média dos números digitados; 
 o maior número digitado; 
 o menor número digitado; 
 a média dos números pares. 
 
Repita ... até 
Esta estrutura repete uma seqüência de comandos até que uma determinada condição (especificada através 
de uma expressão lógica) seja satisfeita. 
repita 
 <seqüência-de-comandos> 
ate <expressão-lógica> 
repita Indica o início do laço. 
ate <expressão-
lógica> 
Indica o fim da <seqüência-de-comandos> a serem repetidos. Cada vez que o 
programa chega neste ponto, <expressão-lógica> é avaliada: se seu resultado 
for FALSO, os comandos presentes entre esta linha e a linha repita são 
executados; caso contrário, a execução prosseguirá a partir do primeiro comando 
após esta linha. 
Considerando ainda o mesmo exemplo: 
algoritmo "Números de 1 a 10 (com repita)" 
var j: inteiro 
inicio 
j <- 1 
repita 
 escreva (j:3) 
 j <- j + 1 
ate j > 10 
fimalgoritmo 
Importante: Como o laço repita...ate testa sua condição de parada depois de executar sua seqüência de 
comandos, esta seqüência poderá ser executada uma ou mais vezes. 
Comando Interrompa 
As três estruturas de repetição acima permitem o uso do comando interrompa, que causa uma saída 
imediata do laço. Embora esta técnica esteja de certa forma em desacordo com os princípios da programação 
estruturada, o comando interrompa foi incluído no VisuAlg por ser encontrado na literatura de introdução à 
programação e mesmo em linguagens como o Object Pascal (Delphi/Kylix), Clipper, VB, etc. Seu uso é 
exemplificado a seguir: 
algoritmo "Números de 1 a 10 (com interrompa)" 
var x: inteiro 
inicio 
x <- 0 
repita 
 x <- x + 1 
 escreva (x:3) 
 16 
 se x = 10 entao 
 interrompa 
 fimse 
ate falso 
fimalgoritmo 
O VisuAlg permite ainda uma forma alternativa do comando repita...ate, com a seguinte sintaxe: 
algoritmo "Números de 1 a 10 (com interrompa) II" 
var x: inteiro 
inicio 
 x <- 0 
 repita 
 x <- x + 1 
 escreva (x:3) 
 se x = 10 entao 
 interrompa 
 fimse 
 fimrepita 
fimalgoritmo 
Com esta sintaxe alternativa, o uso do interrompa é obrigatório, pois é a única maneira de se sair do laço 
repita...fimrepita; caso contrário, este laço seria executado indeterminadamente. 
Exercícios 
1) Elabore um algoritmo que simule uma pesquisa de IBOPE para saber qual é o candidato a prefeito 
preferido por um determinado público. Para isso foram entrevistadas 2000 pessoas. Cada pessoa 
respondeu o código de seu candidato (1, 2 ou 3). Mostrar a quantidade de votos de cada candidato, bem 
como o candidato mais votado. 
 
2) Um determinado frigorífico controla sua boiada colocando no pescoço de cada boi uma plaqueta com um 
código e o peso do boi. Sabendo que o frigorífico possui 300 bois, elabore um algoritmo que calcule e 
imprima o código e o peso do boi mais gordo, bem como código e o peso do boi mais magro. 
 
3) Um cinema vende seus ingressos da seguinte maneira: pessoa com menos de 14 anos paga R$ 5,00 e 
maiores de 14 anos paga R$ 8,00. Sabendo que a capacidade máxima do cinema é para um público de 
2000 pessoas, elabore um algoritmo que calcule e imprima a quantidade de ingressos vendidos, bem como 
o valor recebido pelo caixa. Encerrar o programa quando for digitado 00 (zero) para a idade. 
Dica: Utilize o comando repita ... até que facilita o processamento. 
 
4) Faça um algoritmo que: 
 leia um número indeterminado de linhas contendo cada uma a idade de um indivíduo. A última linha, 
que não entrará nos cálculos, contém o valor da idade igual a zero; 
 calcule e escreva a idade média deste grupo de indivíduos. 
 
Vetor 
Um vetor é uma variável composta homogênea unidimensional formada por uma seqüência de variáveis, todas 
do mesmo tipo, com o mesmo identificador (mesmo nome) e alocadas seqüencialmente na memória. Uma vez 
que as variáveis têm o mesmo nome, o que as distingue é um índice, que referencia sua localização dentro da 
estrutura. 
 
 17 
A declaração de um vetor apresenta a seguinte sintaxe: 
<lista-de-variáveis> : vetor "["<lista-de-intervalos>"]" de <tipo-de-dado> 
Na <lista-de-variáveis>, os nomes das variáveis estão separados por vírgulas. Na <lista-de-
intervalos>, os <intervalo> são separados por vírgulas, e têm a seguinte sintaxe: 
<intervalo>: <valor-inicial> .. <valor-final> 
Na versão atual do VisuAlg, tanto <valor-inicial> como <valor-final> devem ser inteiros. Além disso, 
exige-se evidentemente que <valor-final> seja maior do que <valor-inicial>. 
Exemplos: 
var vet: vetor [1..10] de real 
 z: vetor [0..4] de inteiro 
 
A declaração de vetores é análoga à linguagem Pascal: a variável vet acima tem 10 elementos, com os 
índices de [1] a [10], enquanto z corresponde a 5 elementos com índices [0], [1], [2], [3], [3]. O número total de 
variáveis suportado pelo VisuAlg é 500 (cada elemento de um vetor é contado individualmente). 
Exemplos de vetor: 
 VAR 
 x: vetor[1..10] de real 
 
x 
 1 2 3 4 5 6 7 8 9 10 
 
VAR 
 lista: vetor[0..5] de caracter 
 
lista 
 0 1 2 3 4 5 
 
 
Exercícios 
1) O que será impresso no algoritmo abaixo? 
 
Algoritmo “teste” 
var 
 vet: vetor[1..5] de inteiro 
 i, x: inteiro 
inicio 
 vetor[1] <- 12 
 vetor[2] <- vetor[1] - 2 
 vetor[3] <- 4 
 vetor[4] <- 5 
 vetor[5] <- 15 
 x <- vetor[2] 
 escreval(x) 
 x <- vetor[1] + vetor[3] 
 escreval(x) 
 x <- vetor[vetor[4]] 
 escreval(x) 
 18 
fimalgoritmo 
 
2) Faça um algoritmo que carregue um vetor de 6 elementos numéricos inteiros; calcule e imprima a 
quantidade de números menores que 50. 
 
3) Faça um algoritmo que receba as notas da primeira prova de 10 alunos e armazene essas notas em um 
vetor. Receba as notas da Segunda prova de 10 alunos e armazene essas em outro vetor. Calcule e 
imprima a média entre essas duas notas de cada aluno. 
 
4) Faça um algoritmo que carregue um vetor de 50 números inteiros e imprima o maior elemento desse vetor. 
 
5) Faça um algoritmo que leia um vetor com 20 números reais, calcule e imprima a soma dos elementos 
desse vetor.