Boa noite, já quebrei a cabeça p/ fazer o exercício acima e não consegui montar a logica no portugol, como eu faço essa questão, me ajudem por favor.

Boa noite!

Dependendo de como estiver sendo trabalhadas as regras do português estruturado aí na sua escola ou faculdade o seu código ficará mais ou menos assim:

Algoritmo "Controle_de_Xerox"

// Disciplina   :
// Professor   :
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 06/03/2022

Var

// Seção de Declarações das variáveis 
   quantidade_de_copias : Real;
   preco_por_copia : Real;
   total_a_pagar : Real;
   tipo_de_usuario : Inteiro;

Inicio

   // Iniciando os valores das variáveis.
   quantidade_de_copias := 0.0
   preco_por_copia := 0.0
   total_a_pagar := 0.0
   tipo_de_usuario := 0

   escreva("Quantas cópias você vai tirar? ")
   leia(quantidade_de_copias)

   escreval("") // Serve para escrever uma linha em branco, pular uma linha.
   
   escreval("TABELA DE CÓDIGOS DE USUÁRIOS")
   escreval("") // Serve para escrever uma linha em branco, pular uma linha.

   escreval("Professor (Preço por Cópia: R$0,07): código 12;")
   escreval("Aluno (Preço por Cópia: R$0,15): código 10;")
   escreval("Direção (Preço por Cópia: R$0,00): código 1;")
   escreval("Não aluno (Preço por Cópia: R$0,20): código 15.")

   escreval("") // Serve para escrever uma linha em branco, pular uma linha.
   escreva("Digite qual é o tipo de usuário, conforme os códigos acima: ")
   leia(tipo_de_usuario)
   
   // Verifica o tipo de usuário e guarda o valor a ser cobrado por cópia.
   se (tipo_de_usuario = 12) entao
      preco_por_copia := 0.07
   fimse

   // Verifica o tipo de usuário e guarda o valor a ser cobrado por cópia.
   se (tipo_de_usuario = 10) entao
      preco_por_copia := 0.15
   fimse

   // Verifica o tipo de usuário e guarda o valor a ser cobrado por cópia.
   se (tipo_de_usuario = 1) entao
      preco_por_copia := 0.0
   fimse

   // Verifica o tipo de usuário e guarda o valor a ser cobrado por cópia.
   se (tipo_de_usuario = 15) entao
      preco_por_copia := 0.20
   fimse
   
   // Verifica o tipo de usuário e guarda o valor a ser cobrado por cópia.
   se ( (tipo_de_usuario <> 1) e (tipo_de_usuario <> 10) e (tipo_de_usuario <> 12) e (tipo_de_usuario <> 15) ) entao
      escreval("") // Serve para escrever uma linha em branco, pular uma linha.
      escreva("Você digitou um código de usuário inválido!")
      escreval("") // Serve para escrever uma linha em branco, pular uma linha.
   fimse

   total_a_pagar := quantidade_de_copias * preco_por_copia
   
   escreval("") // Serve para escrever uma linha em branco, pular uma linha.

   escreva("O preço total a pagar é de: R$", total_a_pagar)

Fimalgoritmo

Se você quiser testar no computador o seu algoritmo em portugol você pode usar o Visualg 3.0, disponível para baixar no site: https://visualg3.com.br/baixar-o-visualg3-0/

Este código acima que eu te passei roda perfeitamente no Visualg 3.0. É só você copiar o código inteiro e colar no Visualg 3.0. Lá, com a indentação e os códigos de cores vai ficar mais fácil de você entender o algoritmo.

Espero ter ajudado!

Boa noite!

Sou eu de novo, a mesma pessoa que te passou o código do seu algoritmo.

Eu salvei esse código como PDF com uma formatação mais colorida que pode ficar melhor de ler.

Está neste link: https://www.passeidireto.com/arquivo/105161331

Boa noite!

Muito obrigado, que Deus te retribua e abençoe por ter ajudado na boa fé.