AV2 de Algoritmos (2021 1) - Resolvida

Prévia do material em texto

FACULDADE LOURENÇO FILHO
CURSO DE BACHARELADO EM SISTEMAS DE INFORMAÇÃO
Aluno(a): _______________________________ Matrícula:___________
Data: 18/05/2021 Período: 2021.1
DISCIPLINA: ALGORITMOS Prof°: ANDRÉ BARROS
2ª AVALIAÇÃO PARCIAL
1) Um algoritmo que lê a média de um aluno e imprime a situação do mesmo de
acordo com a média lida está representado no fluxograma abaixo: 
Elabore um algoritmo em pseudocódigo equivalente ao fluxograma mostrado (2
pontos)
Versão Algoritmo
Algoritmo SituacaoAluno
var Media: real
Início
escreva “Informe a média”
leia (Media)
se (Media >=7) então
escreva “Aprovado”
senão
se (Media >=5) então
escreva “Recuperação”
senão
escreva “Reprovado”
fim-se
fim-se
Fim
Versão Visualg
Algoritmo "SituacaoAluno"
var Media: real
inicio
 escreval("Informe a média")
 leia (Media)
 se (Media >=7) entao
 escreval("Aprovado")
 senao
 se (Media >=5) entao
 escreval ("Recuperação")
 senao
 escreval ("Reprovado")
 fimse
 fimse
fimalgoritmo
2) Elabore um algoritmo em pseudocódigo que leia 100 números inteiros, calcule
e imprima: (4 pontos)
a) O maior e o menor número informado.
b) Quantas vezes se repete o maior número informado.
c) A média aritmética dos números informados.
Versão Algoritmo
Algoritmo ListaNumeros
var N, maior, menor, repete, soma, i: inteiro
media: real
Início
escreva “Informe 100 números”
leia N
maior ← N
menor ← N
repete ← 1
soma ← N
para i de 1 até 99 faça
leia N
se (N = maior) então
repete ← repete + 1
fim-se
se (N > maior) então
maior ← N
repete ← 1
fim-se
se (N < menor) então
menor ← N
fim-se
soma ← soma + N
fim-para
media ← soma / 100
escreva “maior número = ”, maior, “ e menor número = ”, menor
escreva “o maior número aparece ”, repete , “ vezes na lista”
escreva “media aritmética dos números = ”, media
Fim
Versão Visualg (com 10 números, para simplificar)
Algoritmo "ListaNumeros"
var N, maior, menor, repete, soma, i: inteiro
 media: real
inicio
 escreval("Informe 10 numeros")
 leia (N)
 maior <- N
 menor <- N
 repete <- 1
 soma <- N
 para i de 1 ate 9 faca
 leia (N)
 se (N = maior) entao
 repete <- repete + 1
 fimse
 se (N > maior) entao
 maior <- N
 repete <- 1
 fimse
 se (N < menor) entao
 menor <- N
 fimse
 soma <- soma + N
 fimpara
 
 media<-soma/10
escreval("maior numero = ", maior," e menor numero = ",menor)
escreval("o maior numero aparece ",repete," vezes na lista")
escreval("media aritmetica dos numeros = ", media)
fimalgoritmo 
Versão Visualg (com 10 números, para simplificar) – Usando Vetores 
Algoritmo "ListaNumeros"
var maior, menor, repete, soma, i: inteiro
 media: real
 N: vetor[1..10] de inteiro
inicio
 escreval("Informe 10 numeros")
 leia (N[1])
 maior <- N[1]
 menor <- N[1]
 repete <- 0
 soma <- N[1]
 para i de 2 ate 10 faca
 leia (N[i])
 se (N[i] > maior) entao
 maior <- N[i]
 fimse
 se (N[i] < menor) entao
 menor <- N[i]
 fimse
 soma <- soma + N[i]
 fimpara
 
 media<-soma/10
 
 para i de 1 ate 10 faca
 se (N[i] = maior) entao
 repete <- repete + 1
 fimse
 fimpara
 
escreval("maior numero = ", maior," e menor numero = ",menor)
escreval("o maior numero aparece ",repete," vezes na lista")
escreval("media aritmetica dos numeros = ", media)
fimalgoritmo
3) Foram entrevistados 500 alunos de uma faculdade. De cada um deles foram
colhidas as seguintes informações: o nome, o código do curso que frequenta
(1 – Direito, 2 – Sistemas de Informação, 3 – Administração) e sua idade.
Elabore um algoritmo que processe esses dados e forneça as seguintes
informações: (4 pontos)
a) Número de alunos por curso. 
b) Número de alunos com idade na faixa de 16 a 18 anos.
c) Nome e idade do aluno mais velho.
d) O curso com a maior média de idade.
Versão Algoritmo
Algoritmo Faculdade
var nome: cadeia
curso, idade, i: inteiro
q1, q2, q3, jovens: inteiro
nomeMV: cadeia
idadeMV: inteiro
med1, med2, med3, mm: real
soma1, soma2, soma3: inteiro
cmm: inteiro
Início
q1<-0
q2<-0
q3<-0
jovens <- 0
idadeMV <- 0
soma1<-0
soma2<-0
soma3<-0
med1<-0
med2<-0
med3<-0
escreva"Informe os dados dos 500 alunos:"
para i de 1 até 500 faça
escreva "Nome:"
leia nome
escreva "Curso: 1 - Direito, 2 - Sistemas, 3 - Administração"
leia curso
escreva "Idade:"
leia idade
caso curso
seja 1 faça
q1 <- q1 + 1
soma1<-soma1 + idade
seja 2 faça
q2 <- q2 + 1
soma2<-soma2 + idade
seja 3 faça
q3 <- q3 + 1
soma3<-soma3 + idade
fim-caso
se (idade >= 16) e (idade <= 18) então
jovens <- jovens + 1
fim-se
se (idade > idadeMV) então
idadeMV <- idade
nomeMV <- nome
fim-se
fim-para
se (q1>0) então
med1 <- soma1/q1
fim-se
se (q2>0) então
med2 <- soma2/q2
fim-se
se (q3>0) então
med3 <- soma3/q3
fim-se
se (med1 > med2) então
cmm <- 1
 mm <- med1
senão
cmm <- 2
 mm <- med2
fim-se
se (med3 > mm) então
cmm <- 3
mm <- med3
fim-se
escreva "Quantidade de alunos de Direito:", q1
escreva "Quantidade de alunos de Sistemas:", q2
escreva "Quantidade de alunos de Administração:", q3
escreva "Quantidade de alunos de 16 a 18 anos:", jovens
escreva "Nome do aluno mais velho:", nomeMV
escreva "Idade do aluno mais velho:", idadeMV
escreva "Código do curso com maior média de idade:", cmm
escreva "Maior média de idade:", mm
Fim
Versão Visualg (com 5 entrevistados, para simplificar)
Algoritmo "Faculdade"
var nome: caractere
 curso, idade, i: inteiro
 q1, q2, q3, jovens: inteiro
 nomeMV: caractere
 idadeMV: inteiro
 med1, med2, med3, mm: real
 soma1, soma2, soma3: inteiro
 cmm: inteiro
inicio
 q1<-0
 q2<-0
 q3<-0
 jovens <- 0
 idadeMV <- 0
 soma1<-0
 soma2<-0
 soma3<-0
 med1<-0
 med2<-0
 med3<-0
 escreval("Informe os dados dos 5 alunos:")
 para i de 1 ate 5 faca
 escreval("Nome:")
 leia (nome)
 escreval ("Curso: 1 - Direito, 2 - Sistemas, 3 - Administração")
 leia (curso)
 escreval ("Idade:")
 leia (idade)
 escolha curso
 caso 1
 q1 <- q1 + 1
 soma1<-soma1 + idade
 caso 2
 q2 <- q2 + 1
 soma2<-soma2 + idade
 caso 3
 q3 <- q3 + 1
 soma3<-soma3 + idade
 fimescolha
 se (idade >= 16) e (idade <= 18) entao
 jovens <- jovens + 1
 fimse
 se (idade > idadeMV) entao
 idadeMV <- idade
 nomeMV <- nome
 fimse
 fimpara
 se (q1>0) entao
 med1 <- soma1/q1
 fimse
 se (q2>0) entao
 med2 <- soma2/q2
 fimse
 se (q3>0) entao
 med3 <- soma3/q3
 fimse
 se (med1 > med2) entao
 cmm <- 1
 mm <- med1
 senao
 cmm <- 2
 mm <- med2
 fimse
 se (med3 > mm) entao
 cmm <- 3
 mm <- med3
 fimse
 escreval ("Quantidade de alunos de Direito:", q1)
 escreval ("Quantidade de alunos de Sistemas:", q2)
 escreval ("Quantidade de alunos de Administração:", q3)
 escreval ("Quantidade de alunos de 16 a 18 anos:", jovens)
 escreval ("Nome do aluno mais velho:", nomeMV)
 escreval ("Idade do aluno mais velho:", idadeMV)
 escreval ("Código do curso com maior média de idade:", cmm)
 escreval ("Maior média de idade:", mm)
Fimalgoritmo
	FACULDADE LOURENÇO FILHO
	CURSO DE BACHARELADO EM SISTEMAS DE INFORMAÇÃO
	DISCIPLINA: ALGORITMOS Prof°: ANDRÉ BARROS