econometria III aula arima

Esta é uma pré-visualização de arquivo. Entre para ver o arquivo original

* Modelando PassThrough no Brasil
* Refs: http://www.scielo.br/pdf/ee/v46n2/0101-4161-ee-46-02-0343.pdf
* http://www.scielo.br/pdf/rec/v18n3/1415-9848-rec-18-03-00333.pdf
* https://www.anpec.org.br/encontro/2017/submissao/files_I/i7-4f9f3aa77740343b1ae17ed47a4e67c1.pdf
* Copie o caminho da pasta onde estão os dados
cd "C:\Users\Lenovo\Documents\cursos\econometria III UFRJ"
import excel "pass through 2017.xls", sheet("Dados") firstrow
rename Data data
saveold "ppp_passth2017.dta", replace
use "ppp_passth2017.dta", clear
** Arrumando as datas (quando data é um string)
destring data, replace
gen time=_n
gen year=int(data)
gen uno=1
sort year
by year: gen mes=sum(uno)
gen Data=ym(year, mes)
format Data %tm
* há um erro na variável IPA nos EUA
replace US_IPA=US_IPA*10 if data<2009.01
 
* definindo time series
tsset Data
* Criando variⷥis em logs para modelagem
* Usando minúsculas para logs
gen ipca=log(IPCA)
gen e=log(E)
* variáveis em diferenças
gen infl=d.ipca
gen de=d.e
******************** An�lise ARIMA para inflação
twoway (line ipca Data, sort) (line infl Data , yaxis(2)), scheme(s2mono)
 
* Análise posterior a 2004 para evitar pico de inflação de 2003.
drop if data<2005.01
twoway (line ipca Data, sort) (line infl Data , yaxis(2)), scheme(s2mono)
* Correlogramas em nivel e em diferenças
corrgram ipca , yw
corrgram infl , yw
* para referencia: intervalo de confiança para significância ACD
display 1/sqrt(_N)
display 1.96*1/sqrt(_N)
*gerando tendência
gen trend=_n
* I. Modelo simples, com tendência linear e sazonalidade
reg ipca trend i.mes
predict resipca_TS,r
estat ic
* Modelo com tendência não elimina raiz unitária
corrgram resipca_TS, yw
drop resipca_TS
* II. y~ARIMA(1,1,0) e Dy~ARIMA(1,0,0) são equivalentes
* Modelo simples para ipca - ARIMA(1,1,0)
arima ipca, arima(1,1,0)
predict resipca_ARIMA110,r
* Modelo equivalente para ipca: infl - ARIMA(1,0,0)
arima infl, arima(1,0,0)
predict resinfl_ARIMA100,r
*Veja que no gráfico os resíduos são iguais
twoway (line resipca_ Data) (line resinfl_ Data)
drop resipca_ARIMA110 resinfl_ARIMA10
* III. SELEÇÂO DE MODELOS ARIMA - baseado na série estacionária - infl
corrgram infl, yw
* Correlogama inflação sugere ARIMA(1,0,0) com sazonalidade OU ARIMA(12,0,0)
* III.1 - Modelos para infl - ARIMA(1,0,0)
arima infl, arima(1,0,0)
estimates store ARIMA100
estat ic
predict resinfl_ARIMA100,r
* resíduos ruído branco?
corrgram resinfl_ARIMA100 , yw
* III.2 - Modelos para infl - ARIMA(2,0,0)
arima infl, arima(2,0,0)
estimates store ARIMA200
estat ic
predict resinfl_ARIMA200,r
* resíduos ruído branco?
corrgram resinfl_ARIMA200 , yw
* III.3 - Modelos para infl - ARIMA(0,0,1)
arima infl, arima(0,0,1)
estimates store ARIMA001
estat ic
predict resinfl_ARIMA001,r
* resíduos ruído branco?
corrgram resinfl_ARIMA001 , yw
* III.4 - Modelos para infl - ARIMA(1,0,0) com dummies sazonais
xi: arima infl i.mes, arima(1,0,0)
estimates store ARIMA100S
estat ic
predict resinfl_ARIMA100S,r
* resíduos ruído branco?
corrgram resinfl_ARIMA100S , yw
* III.5 - Modelos para infl - ARIMA(12,0,0)
xi: arima infl, arima(12,0,0)
estimates store ARIMA1200
estat ic
predict resinfl_ARIMA1200,r
* resíduos ruído branco?
corrgram resinfl_ARIMA1200 , yw
** Olhando o critérios AIC qual dos modelos é o mais recomendado?
** Olhando o critérios SIC qual dos modelos é o mais recomendado?
estimates stat ARIMA100 ARIMA200 ARIMA001 ARIMA100S ARIMA1200
** Olhando critério de resíduos ruído branco qual dos modelos deve ser usado?
corrgram resinfl_ARIMA100 , yw l(24)
corrgram resinfl_ARIMA200 , yw l(24)
corrgram resinfl_ARIMA001 , yw l(24)
corrgram resinfl_ARIMA100S , yw l(24)
corrgram resinfl_ARIMA1200 , yw l(24)
drop resinfl_*
estimates drop ARIMA100 ARIMA200 ARIMA001 ARIMA100S ARIMA1200
***********************************************
******************** An⭩se ARIMA para câmbio
twoway (line e Data, sort) (line de Data , yaxis(2)), scheme(s2mono)
 
* Correlogramas em nivel e em diferenças
corrgram e , yw
corrgram de , yw
* para referencia: intervalo de confiança para significância ACD
display 1/sqrt(_N)
display 1.96*1/sqrt(_N)
* I. Modelo simples, com tendência linear e sazonalidade
reg e trend i.mes
predict rese_TS,r
estat ic
* Modelo com tendência não elimina raiz unitária
corrgram rese_TS, yw
drop rese_TS
* II. SELEÇÂO DE MODELOS ARIMA - baseado na série estacionária - de
corrgram de, yw
* Correlogama deação sugere passeio aleatório (ou ARIMA(2,0,0))
* II.1 - Modelos para e - ARIMA(0,1,0)
arima e, arima(0,1,0)
estimates store ARIMA010
estat ic
predict resde_ARIMA010,r
* resíduos ruído branco?
corrgram resde_ARIMA010 , yw
* II.2 - Modelos para de - ARIMA(1,0,0)
arima de, arima(1,0,0)
estimates store ARIMA100
estat ic
predict resde_ARIMA100,r
* resíduos ruído branco?
corrgram resde_ARIMA100 , yw
* III.3 - Modelos para de - ARIMA(2,0,0)
arima de, arima(2,0,0)
estimates store ARIMA200
estat ic
predict resde_ARIMA200,r
* resíduos ruído branco?
corrgram resde_ARIMA200 , yw
* III.4 - Modelos para de - ARIMA(0,0,1)
arima de, arima(0,0,1)
estimates store ARIMA001
estat ic
predict resde_ARIMA001,r
* resíduos ruído branco?
corrgram resde_ARIMA001 , yw
** Olhando o critérios AIC qual dos modelos é o mais recomendado?
** Olhando o critérios SIC qual dos modelos é o mais recomendado?
estimates stat ARIMA010 ARIMA100 ARIMA200 ARIMA001 
** Olhando critério de resíduos ruído branco qual dos modelos deve ser usado?
corrgram resde_ARIMA010 , yw l(24)
corrgram resde_ARIMA100 , yw l(24)
corrgram resde_ARIMA200 , yw l(24)
corrgram resde_ARIMA001 , yw l(24)
drop resde_*
estimates drop ARIMA010 ARIMA100 ARIMA200 ARIMA001